Craft prototype not working

giuliomoro Yea however, now that I moved to a prototype, it does not want to work combining midiusb.h lol
Ive checked continuity and voltage across these pads, I get a constant 4.96v on these pads, Im getting 5v at craft board, all wires are good, I soldered these to the craft board in hopes I can desolder later as this is mainly proof of concept. I also done a midiusb example which worked, (c note off and on every half second), did craft print which is effected by my new pads meaning it reads the different values, but combining code has unfortunately not worked out. Ive checked and both libraries and ide is up to date as well. Not really sure where to go from here lol, this is the new code I tried to have it run but it did not output midi. If theres some errors or suggestions, please let me know!

#include <Trill.h>
#include <MIDIUSB.h>

Trill trillSensor; // for Trill Craft

void noteOn(byte channel, byte pitch, byte velocity) {
  midiEventPacket_t noteOn = {0x09, 0x90 | channel, pitch, velocity};
  MidiUSB.sendMIDI(noteOn);
}

void noteOff(byte channel, byte pitch, byte velocity) {
  midiEventPacket_t noteOff = {0x08, 0x80 | channel, pitch, velocity};
  MidiUSB.sendMIDI(noteOff);
}

void setup() {
  Serial.begin(115200);
  int ret = trillSensor.setup(Trill::TRILL_CRAFT);
  if(ret != 0) {
    Serial.println("failed to initialise trillSensor");
    Serial.print("Error code: ");
    Serial.println(ret);
  }
}

void loop() {
  delay(100);
  trillSensor.read();

  for(unsigned int i = 0; i < trillSensor.getNumTouches(); i++) {
    // Get the touch size (y)
    float ySize = trillSensor.touchSize(i);

    // Print the touch size
    Serial.print("Touch #");
    Serial.print(i);
    Serial.print(": Size = ");
    Serial.println(ySize);

    // Send MIDI note
    int note = 60 + i; // 60 is MIDI note number for Middle C
    int velocity = ySize * 127;
    if(velocity > 10) { // Set a fixed threshold
      noteOn(0, note, velocity);
      delay(100);
      noteOff(0, note, velocity);
    }
  }
  MidiUSB.flush();
}

got it to work finally, since this is in differential mode, does that mean I cant use an x mode (forget exactly what its called)? Wanted to make a keytar of sorts but keys being the x and y control as well as notes, similar to how a fsr screen can. I have a secondary idea to acheive something similar but may be overkill to use this board for it tbh. Here is the code I used, hopefully I did those tick marks right!

#include <Trill.h>
#include <MIDIUSB.h>

Trill trillSensor; // for Trill Craft
const int numPads = 6; // the number of pads you're using
const int threshold = 20; // Increase the threshold value
bool notePlaying[numPads] = {false}; // Keep track of whether each note is playing

void noteOn(byte channel, byte pitch, byte velocity) {
  midiEventPacket_t noteOn = {0x09, 0x90 | channel, pitch, velocity};
  MidiUSB.sendMIDI(noteOn);
}

void noteOff(byte channel, byte pitch, byte velocity) {
  midiEventPacket_t noteOff = {0x08, 0x80 | channel, pitch, velocity};
  MidiUSB.sendMIDI(noteOff);
}

void setup() {
  Serial.begin(115200);
  int ret = trillSensor.setup(Trill::TRILL_CRAFT);
  if(ret != 0) {
    Serial.println("failed to initialise trillSensor");
    Serial.print("Error code: ");
    Serial.println(ret);
  }
}

void loop() {
  delay(100);
  trillSensor.requestRawData();

  for(int i = 0; i < numPads; i++) {
    if(trillSensor.rawDataAvailable() > 0) {
      int data = trillSensor.rawDataRead();
      int note = 60 + i; // 60 is MIDI note number for Middle C
      int velocity = data / 8; // Scale the raw data to a velocity value
      if(velocity > threshold && !notePlaying[i]) { // If a touch is detected and the note is not already playing
        noteOn(0, note, velocity);
        notePlaying[i] = true; // Mark the note as playing
      } else if(velocity <= threshold && notePlaying[i]) { // If the touch is released and the note is playing
        noteOff(0, note, velocity);
        notePlaying[i] = false; // Mark the note as not playing
      }
    }
  }
  MidiUSB.flush();
}