Arduino Nano ESP32 Sending OSC to Bela

Keyi

Hi all, I am trying to use an Arduino Nano ESP32 to read sensor data and send to Bela through wifi OSC. Is there anything I have to set up on the Bela to receive that data? Thank you!

giuliomoro

If you already have code for your esp32 and you have bela connected to the same network as the esp32, then using something like the Communication/OSC-Pipe example should be a good starting point

Keyi

giuliomoro Hi Giulio, can I just connect the esp32 to the Bela network? If I use the Bela wifi for esp32, do I have to specify any password for the ssid?

giuliomoro

What's the Bela wifi? There is no wifi capability on board Bela unless you provide it via a usb wifi dongle. Did you do that?

Keyi

giuliomoro I didn't. So I just need to specify the Bela network IP address in arduino for OSC sending? I was looking at the OSCwifi example in arduino, am I on the right track?


// Please include ArduinoOSCWiFi.h to use ArduinoOSC on the platform
// which can use both WiFi and Ethernet
#include <ArduinoOSCWiFi.h>
// this is also valid for other platforms which can use only WiFi
// #include <ArduinoOSC.h>

// WiFi stuff
const char* ssid = "your-ssid";
const char* pwd = "your-password";
const IPAddress ip(192, 168, 1, 201);
const IPAddress gateway(192, 168, 1, 1);
const IPAddress subnet(255, 255, 255, 0);

// for ArduinoOSC
const char* host = "192.168.1.200";
const int recv_port = 54321;
const int bind_port = 54345;
const int send_port = 55555;
const int publish_port = 54445;
// send / receive varibales
int i;
float f;
String s;

void onOscReceived(const OscMessage& m) {
    Serial.print(m.remoteIP());
    Serial.print(" ");
    Serial.print(m.remotePort());
    Serial.print(" ");
    Serial.print(m.size());
    Serial.print(" ");
    Serial.print(m.address());
    Serial.print(" ");
    Serial.print(m.arg<int>(0));
    Serial.print(" ");
    Serial.print(m.arg<float>(1));
    Serial.print(" ");
    Serial.print(m.arg<String>(2));
    Serial.println();
}

void setup() {
    Serial.begin(115200);
    delay(2000);

    // WiFi stuff (no timeout setting for WiFi)
#if defined(ESP_PLATFORM) || defined(ARDUINO_ARCH_RP2040)
#ifdef ESP_PLATFORM
    WiFi.disconnect(true, true);  // disable wifi, erase ap info
#else
    WiFi.disconnect(true);  // disable wifi
#endif
    delay(1000);
    WiFi.mode(WIFI_STA);
#endif
    WiFi.begin(ssid, pwd);
    WiFi.config(ip, gateway, subnet);
    while (WiFi.status() != WL_CONNECTED) {
        Serial.print(".");
        delay(500);
    }
    Serial.print("WiFi connected, IP = ");
    Serial.println(WiFi.localIP());

    // publish osc messages (default publish rate = 30 [Hz])

    OscWiFi.publish(host, publish_port, "/publish/value", i, f, s)
        ->setFrameRate(60.f);

    OscWiFi.publish(host, publish_port, "/publish/func", &millis, &micros)
        ->setIntervalMsec(500.f);

    // subscribe osc messages

    OscWiFi.subscribe(bind_port, "/bind/values", i, f, s);

    OscWiFi.subscribe(bind_port, "/lambda/bind/args",
        [&](const int& i, const float& f, const String& s) {
            Serial.print("/lambda/bind/args ");
            Serial.print(i);
            Serial.print(" ");
            Serial.print(f);
            Serial.print(" ");
            Serial.print(s);
            Serial.println();
        });

    OscWiFi.subscribe(recv_port, "/lambda/msg",
        [](const OscMessage& m) {
            Serial.print(m.remoteIP());
            Serial.print(" ");
            Serial.print(m.remotePort());
            Serial.print(" ");
            Serial.print(m.size());
            Serial.print(" ");
            Serial.print(m.address());
            Serial.print(" ");
            Serial.print(m.arg<int>(0));
            Serial.print(" ");
            Serial.print(m.arg<float>(1));
            Serial.print(" ");
            Serial.print(m.arg<String>(2));
            Serial.println();
        });

    OscWiFi.subscribe(recv_port, "/wildcard/*/test", [](const OscMessage& m) {
        Serial.print(m.remoteIP());
        Serial.print(" ");
        Serial.print(m.remotePort());
        Serial.print(" ");
        Serial.print(m.size());
        Serial.print(" ");
        Serial.print(m.address());
        Serial.print(" ");
        Serial.print(m.arg<int>(0));
        Serial.println();
    });

    OscWiFi.subscribe(recv_port, "/need/reply", []() {
        Serial.println("/need/reply");

        int i = millis();
        float f = (float)micros() / 1000.f;
        String s = "hello";

        OscWiFi.send(host, send_port, "/reply", i, f, s);
    });

    OscWiFi.subscribe(recv_port, "/callback", onOscReceived);
}

void loop() {
    OscWiFi.update();  // should be called to receive + send osc

    // or do that separately
    // OscWiFi.parse(); // to receive osc
    // OscWiFi.post(); // to publish osc
}

giuliomoro

Keyi I didn't

So how are the two connected or how are you planning to connect them?

Keyi I was looking at the OSCwifi example in arduino, am I on the right track?

this looks like it is connecting to the WiFi with SSID and password specified in the ssid and pwd variables. If get Bela on the same network, e.g.: using a wifi dongle on Bela or an ethernet cable, then you should set the ip, gateway and subnet to valid values for your network and host should be the IP of Bela on that network. Some info for how to connect bela to wifi are here.

Keyi Sorry I know this should be an arduino question, but it seems that the example kind of works?

Bela shows up on the host computer as a USB device with several functions. Among these, network (which is what allows you to access it via the browser), file storage (BELABOOT) and serial. What you see there is this last one: the serial console on Bela. It has nothing to do with your code or example, it just means that you selected Bela as the (wrong) peripheral to connect the Arduino IDE's Serial Monitor to.

Keyi

Sorry I know this should be an arduino question, but it seems that the example kind of works?

Keyi

giuliomoro Hi Giulio, thank you very much for the reply.

giuliomoro So how are the two connected or how are you planning to connect them?

I just want to let the arduino send OSC to Bela.

I think in that case I won't be using the wifi function. But since i don't have a ethernetn cable or a dongle, I wonder I just need to specify the host to be the IP of Bela network.

giuliomoro

How are you planning to connect Bela and ESP32 then?

Keyi

giuliomoro Hi Giulio, thank you for pointing that out. I think having them connecting to the same wifi network is a way. But it requires a dongle. Do you know any better methods? Thank you.

giuliomoro

Ethernet cable or wifi dongle are the only methods to connect Bela to a network.

Now, if wireless transmission and OSC are not a requisite, then you may be able to connect the Arduino Nano ESP32 to the Bela USB host port and have the two communicate via UART-over-USB .

Keyi

giuliomoro Hi Giulio, my Arduino Nano esp32 has2 UART pinouts for transmitting and recieving. What kind of wiring should be done to connect to the Bela usdhost port? Or can I just use the usb on the arduino itself. (I tried to upload a photo in the thread but I failed).

giuliomoro

UART (physical or via USB) is doable to connect to Bela. Just see if you can figure out the code to send relevant data on the esp32 side.

Keyi

giuliomoro Hi giulio, which pins should I use on the bela mini for physical UART connection? I found a link for enabling the uart port, is the page still effective? https://github.com/BelaPlatform/Bela/wiki/Load-a-device-tree-overlay

What could cause "no such file or directory" message?

Keyi

Keyi Hi Giulio, I managed to connect the arduino to bela mini, but it seems to have a very bad block drop issue. I have the baudrate to 19200. Any solutions to fix the issue? Thanks.

giuliomoro

Oh well I didn't expect you'd be using csound to read from the UART. A quick look at the source code for serialBegin / serialRead opcodes seems to show that they are doing I/O from within the audio thread, which is bad design and explains the behaviour you observe above. They also acknowledge the design issue in the source code: TODO: (might need some kind of threaded buffer-read?).

It looks like there is an arduinoStart/arduinoRead/arduinoStop set of functions which seems to be doing it better (reading the inputs from a dedicated thread), but it assumes that the transmission has some specific format to it (e.g.: We use a 0x80 read to synchonise, and each value is packed with an index; data only sent if it changes.. Maybe there's more documentation on this somewhere?

Keyi

giuliomoro Hey Giulio, thank you for replying. One thing I wanan ask is that is the serial port on Bela should always be "/dev/tty4" regardless of the arduino port I am using? I am checking the arduinoRead opcode here [https://csound.com/manual/arduinoRead.html](https://) and it seems only reads integer from arduino. However, the sensor I am using in arduino is float number. I am trying to see how to make it work by modifying the arduino-Trill to Csound example here .

/*
 ____  _____ _        _
| __ )| ____| |      / \
|  _ \|  _| | |     / _ \
| |_) | |___| |___ / ___ \
|____/|_____|_____/_/   \_\
http://bela.io

\example bar-print

Trill Bar Print
===============

This is an example of how to communicate with the Trill Bar
sensor using the Trill Arduino library.

The sensor is set to Centroid mode and touch location and size
printed to the serial port for each of the 5 different simultaneous
touches.

The accompanying Processing sketch, `TrillBarDisplay.pde`, listens for
touch information on the Arduino serial port* and displays it in a
render of a Trill Bar.

*/

#include <Trill.h>

Trill trillSensor;
boolean touchActive = false;

// put_val( ) - a function to send data values to the Csound
//              "arduinoRead" opcode
// The first argument of the put_val function "int senChan" sets
// the software channel number that Csound reads
// NOTE: "senChan" does "not" define the input pin that is used on
// the Arduino for a specific sensor
// The specific Arduino input pin used by any sensor is assigned
// and set elsewhere in the Arduino sketch and mapped to a
// user-defined put_val "senChan" channel

void put_val(int senChan, int senVal)
        // Set the Csound receive channel "senChan", and read from
        // the sensor data stream "senVal"
{       // The packing of the data is sssssvvv 0vvvvvvv where s is a
        // senChan bit, v a senVal bit and 0 is zero bit, high byte first
  int low = senVal&0x7f;
  int hi = ((senVal>>7)&0x7) | ((senChan&0x1f)<<3);
  Serial.write(low); Serial.write(hi);
}

void setup() {
  // Initialise serial and touch sensor
  Serial.begin(115200);
  int ret = trillSensor.setup(Trill::TRILL_BAR);
  if(ret != 0) {
    Serial.println("failed to initialise trillSensor");
    Serial.print("Error code: ");
    Serial.println(ret);
  }
}

void loop() {
  // Read 20 times per second
  delay(50);
  trillSensor.read();
  if(trillSensor.getNumTouches() > 0) {
    for(int i = 0; i < trillSensor.getNumTouches(); i++) {
int Val1 = trillSensor.touchLocation(i); 
    put_val(1,Val1);            // Val1 is assigned to Csound arduinoRead Channel 1 
int Val2 = trillSensor.touchSize(i);                           
    put_val(2,Val2);            // Val2 is assigned to Csound arduinoRead Channel 2
    }
    touchActive = true;
          put_val(3,1);
  }
  else if(touchActive) {
    touchActive = false;
          put_val(3,0);
  } 
    Serial.write(0xf8); // Synchronization Byte - (essential!) marks beginning of new serial frame
}

giuliomoro

Keyi is the serial port on Bela should always be "/dev/ttyS4" regardless of the arduino port I am using?

if you are using The pins for TTY4 then /dev/ttyS4 is the one you need, regardless of what you are using on the Arduino.

Keyi it seems only reads integer from arduino. However, the sensor I am using in arduino is float number. I am trying to see how to make it work by modifying the arduino-Trill to Csound example here .

You can multiply your floating point number by a reasonable value to make it an integer with reasonable resolution. I seem to understand from the arduino code provided at the documentation page you link that you can pass values between 0 and 16383, so for example if your value is a floating point between 0 and 1 , then you can multiply it by 16383 and obtain an integer that can be passed from Arduino to CSound.

Keyi

giuliomoro then you can multiply it by 16383 and obtain an integer that can be passed from Arduino to CSound.

And then devide by 16383 in Csound to return back to the original float?

giuliomoro

yes

Keyi

giuliomoro Thank you giulio. One thing I am not clear is that, if the number is a three point floating point, then it won't be an integer after times 16383, right?