having a problem using Bela Flex and Breakout

BillW

I'm trying to connect a Trill Flex to a Adafruit Trinket M0 SAMD21. My code compiles, everything seems connected correctly, but the sensor doesn't show up scanning IC2 at all.

The only thing that seems strange is my board looks different than the ones on the Bela site. It says Revision C2 instead of A2 on the pictures on the Bela site. Also, I inserted the sensor into the connector with the black strip facing up, and the pins touching the board. It seems like its all the way in unless there's a trick to get it to go in a little further.

Are there any known caveats with the Trinket? I'm using the TinyUSB stack.

I'm also having problems getting a reading after switching to a Teensy 4.

Thx

edit - some additional info:
Rev C2 board
Teensy 4.0
Trill Arduino library
All channels reading 4095
I2C device found at 0x48
Firmware version 3, 30 channels detected

giuliomoro

You said:

BillW but the sensor doesn't show up scanning IC2 at all.

but then:

Teensy 4.0
All channels reading 4095
I2C device found at 0x48
Firmware version 3, 30 channels detected

So: it seems that on Teensy 4.0 it shows up and it returns its version number from i2c.

All channels reading 4095

I think from the picture that the flex PCB is mounted upside down. Can you send a better picture so I can tell for certain? The silkscreen on the flex sensor should be on the bottom. Also, remove the flex PCB and read the raw sensor values while touching the pins at the back of the FFC connector: do you see any valid readings?

Are there any known caveats with the Trinket? I'm using the TinyUSB stack.

Not that I know of. Are there I2C pullups? Not sure how the TinyUSB stack is relevant here.

BillW

giuliomoro

Sorry, I mixed up two different versions of what I was trying. The Trinket didn't seem like it was connecting at all. So I gave up and switched to a Teensy 4.0 and can connect to the board but don't read any touch.

Re TinyUSB, that's the library I'm using to connect to the teensy from my computer. Not sure re germain, I'm just starting out!

When I disconnect the flex and just touch the pins, I do see some voltage change. I'd thought the flex might be upside down, but it matches the images I see online, unless they changed something.

A real NOOB question, but is there a covering I need to peel off the flex? It's clearly not touching the contacts, no matter how I orient it.

giuliomoro

Again,

giuliomoro Are there I2C pullups?

A quick online search suggests that there are no pullups on the Trinket's I2C pins. Add external resistors, most any value between 1k and 10k would work, between SDA and Vcc and between SCL and Vcc, see if that makes it work. See here or check Trinket-specific documentation.

giuliomoro

No peeling needed, the orientation looks OK.

Can you show your code? If using the Arduino library with the default sensor you need to change the prescaler in order not to saturate the pads, see here: https://github.com/BelaPlatform/Trill-Arduino/blob/master/examples/flex-print-slider/flex-print-slider.ino#L41-L64

Are you doing that? The sleep before and after the setPrescaler() call are important, and so is the updateBaseline() call .

BillW

Ah, interesting. I just got that example, flex-print-slider to work.

My code is just trying to get the raw data. And I assumed all the necessary setup happened within trill.setup()!

#include <Wire.h>
#include <Trill.h>

Trill trill;

void setup() {
  Serial.begin(9600);
  while (!Serial);
  delay(500);
  
  int result = trill.setup(Trill::TRILL_FLEX, 0x48);
  if (result == 0) {
    Serial.println("Trill Flex found!");
    trill.setMode(Trill::DIFF);  
    delay(100);
    trill.updateBaseline();
    Serial.println("Ready - do not touch for 2 seconds");
    delay(2000);
    trill.updateBaseline();
    Serial.println("Baseline set - touch now");
  } else {
    Serial.print("Not found, error: ");
    Serial.println(result);
  }
}

void loop() {
  trill.requestRawData();
  delay(10);
  int maxVal = 0;
  int maxIdx = 0;
  int count = 0;
  while (trill.rawDataAvailable() > 0) {
    int val = trill.rawDataRead();
    if (abs(val) > abs(maxVal)) {
      maxVal = val;
      maxIdx = count;
    }
    count++;
  }
  Serial.print("Max channel: ");
  Serial.print(maxIdx);
  Serial.print("  Value: ");
  Serial.println(maxVal);
  delay(100);
}

BillW

FYI - adding your suggestion works! Thanks so much.

#include <Wire.h>
#include <Trill.h>

Trill trill;
int lastTouches = -1;

void setup() {
  Serial.begin(9600);
  while (!Serial);
  delay(500);
  
  int result = trill.setup(Trill::TRILL_FLEX, 0x48);
  if (result == 0) {
    Serial.println("Trill Flex found!");
    trill.setMode(Trill::CENTROID);
    delay(100);
    trill.setPrescaler(4);  // reduce prescaler for flex
    delay(200);             // sleep after setPrescaler
    trill.updateBaseline();
    delay(200);             // sleep after updateBaseline
    Serial.println("Ready - do not touch for 2 seconds");
    delay(2000);
    trill.updateBaseline();
    Serial.println("Baseline set - touch now");
  } else {
    Serial.print("Not found, error: ");
    Serial.println(result);
  }
}

void loop() {
  trill.read();
  int touches = trill.getNumTouches();
  if (touches != lastTouches || touches > 0) {
    Serial.print("Touches: ");
    Serial.print(touches);
    if (touches > 0) {
      Serial.print("  Location: ");
      Serial.println(trill.touchLocation(0));
    } else {
      Serial.println();
    }
    lastTouches = touches;
  }
  delay(50);
}

Going to give it a shot with the trinket again.
Update: I can't get the trinket to see the Trill, even when I use the flex-print-slider example.

giuliomoro

Try this

#include <Wire.h>
#include <Trill.h>

Trill trill;

void setup() {
  Serial.begin(9600);
  while (!Serial);
  delay(500);
  
  int result = trill.setup(Trill::TRILL_FLEX, 0x48);
  if (result == 0) {
    Serial.println("Trill Flex found!");
    delay(10);
    trill.setMode(Trill::DIFF);  
    delay(10);
    trill.setPrescaler(3);
    delay(10);
    trill.updateBaseline();
    delay(100);
    Serial.println("Baseline set - touch now");
  } else {
    while(1) {
      Serial.print("Not found, error: ");
      Serial.println(result);
     }
  }
}

void loop() {
  trill.requestRawData();
  delay(10);
  int maxVal = 0;
  int maxIdx = 0;
  int count = 0;
  while (trill.rawDataAvailable() > 0) {
    int val = trill.rawDataRead();
    if (abs(val) > abs(maxVal)) {
      maxVal = val;
      maxIdx = count;
    }
    count++;
  }
  Serial.print("Max channel: ");
  Serial.print(maxIdx);
  Serial.print("  Value: ");
  Serial.println(maxVal);
  delay(100);
}

BillW

Your code worked with the Teensy 4 but not on the Trinket. The Trinket outputs "Not found, error 2"

I'm about to give up on the trinket, though I have another one coming in the mail, maybe this one's problematic.

FYI, this is the full sketch that does everything I wanted at this point, assuming I use Teensy, which is just a simple midi slider for RME Totalmix. I'll probably add something like double tap to toggle mute.

I just wanted it to work on the Trinket because it's smaller and cheaper for this simplistic project. And I have a more complex idea that will go on the Teensy

Any suggestion for a cheap, small board that powers off usb and would run this very simple midi controller that plays well with Bela?

#include <Wire.h>
#include <Trill.h>

Trill trill;
int lastVal = -1;

void setup() {
  usbMIDI.begin();
  
  int result = trill.setup(Trill::TRILL_FLEX, 0x48);
  if (result == 0) {
    trill.setMode(Trill::CENTROID);
    delay(100);
    trill.setPrescaler(4);
    delay(200);
    trill.updateBaseline();
    delay(200);
    delay(2000);
    trill.updateBaseline();
  }
}

void loop() {
  trill.read();
  
  if (trill.getNumTouches() > 0) {
    int location = trill.touchLocation(0);
    int val = map(location, 0, 3712, 0, 127);
    val = constrain(val, 0, 127);
    
    if (abs(val - lastVal) > 1) {
      usbMIDI.sendControlChange(7, val, 1);
      lastVal = val;
    }
  }
  
  delay(20);
  while (usbMIDI.read()) {}
}

BillW

giuliomoro

Fortunately I had some 10k resistors, so I put 2 in parallel for SDA and SCL and it works perfectly!!

Thanks for your assistance. Sorry, I glossed over the ic2 point and was focused on the code and chip. But the good part is I've built the same code for 3 different cpu's now. Also using several different pots and encoders. But I really like the results with the flex the most. It's just a volume controller for TotalMix and has a doubletap to toggle mute. But a great learning experience.

Much thanks.

#include <Wire.h>
#include <Trill.h>
#include <MIDI.h>

Adafruit_USBD_MIDI usb_midi;
MIDI_CREATE_INSTANCE(Adafruit_USBD_MIDI, usb_midi, MIDI);

Trill trill;
int lastVal = -1;
int savedVal = 64;
bool muted = false;

unsigned long lastTapTime = 0;
bool wasTouching = false;
unsigned long touchStartTime = 0;
const unsigned long doubleTapWindow = 400;
const unsigned long minTapDuration = 20;
const unsigned long maxTapDuration = 300;

void setup() {
  usb_midi.begin();
  MIDI.begin(MIDI_CHANNEL_OMNI);
  

  int result = trill.setup(Trill::TRILL_FLEX, 0x48);
  if (result == 0) {
    trill.setMode(Trill::CENTROID);
    delay(100);
    trill.setPrescaler(4);
    delay(200);
    trill.updateBaseline();
    delay(200);
    delay(2000);
    trill.updateBaseline();
  }
  while (!USBDevice.mounted()) delay(1);
}

void loop() {
  trill.read();
  bool touching = trill.getNumTouches() > 0;
  unsigned long now = millis();

  if (touching && !wasTouching) {
    touchStartTime = now;
  }

  if (!touching && wasTouching) {
    unsigned long touchDuration = now - touchStartTime;
    if (touchDuration >= minTapDuration && touchDuration <= maxTapDuration) {
      if (now - lastTapTime < doubleTapWindow) {
        muted = !muted;
        if (muted) {
          savedVal = lastVal;
          MIDI.sendControlChange(7, 0, 1);
        } else {
          MIDI.sendControlChange(7, savedVal, 1);
          lastVal = savedVal;
        }
      }
      lastTapTime = now;
    }
  }

  wasTouching = touching;

  if (touching && !muted) {
    int location = trill.touchLocation(0);
    int val = map(location, 0, 3712, 0, 127);
    val = constrain(val, 0, 127);

    if (abs(val - lastVal) > 1) {
      MIDI.sendControlChange(7, val, 1);
      lastVal = val;
    }
  }

  delay(20);
  MIDI.read();
}```